Update Maven release scripts

Summary:
Reuse the gradle setup we've built for Litho which allows for parallel publishing to Bintray and Maven Central in addition to Sonatype Snapshots.

This appears not to break the existing jcenter deploy script which is pretty great.

Reviewed By: emilsjolander

Differential Revision: D5020576

fbshipit-source-id: 3ef163ccbfe91c6858b051d39dcf237ca388e18d

gradle/android-tasks.gradle

@@ -0,0 +1,47 @@
+// Android tasks for Javadoc and sources.jar generation
+
+afterEvaluate { project ->
+    if (POM_PACKAGING == 'aar') {
+        task androidJavadoc(type: Javadoc) {
+            source = android.sourceSets.main.java.srcDirs
+            exclude '**/pom.xml'
+            exclude '**/proguard_annotations.pro'
+            classpath += files(android.bootClasspath)
+        }
+
+        task androidJavadocJar(type: Jar) {
+            classifier = 'javadoc'
+            from androidJavadoc.destinationDir
+        }
+
+        task androidSourcesJar(type: Jar) {
+            classifier = 'sources'
+            from android.sourceSets.main.java.srcDirs
+        }
+
+        android.libraryVariants.all { variant ->
+            def name = variant.name.capitalize()
+            task "jar${name}"(type: Jar, dependsOn: variant.javaCompile) {
+                from variant.javaCompile.destinationDir
+            }
+        }
+
+        artifacts.add('archives', androidJavadocJar)
+        artifacts.add('archives', androidSourcesJar)
+    }
+
+    if (POM_PACKAGING == 'jar') {
+        task javadocJar(type: Jar, dependsOn: javadoc) {
+            classifier = 'javadoc'
+            from javadoc.destinationDir
+        }
+
+        task sourcesJar(type: Jar, dependsOn: classes) {
+            classifier = 'sources'
+            from sourceSets.main.allSource
+        }
+
+        artifacts.add('archives', javadocJar)
+        artifacts.add('archives', sourcesJar)
+    }
+}