e5a4003af5
Summary: Pull Request resolved: https://github.com/facebook/yoga/pull/1382 X-link: https://github.com/facebook/react-native/pull/39437 Have been running into places where C++ 20 makes life easier for use like `std::bit_cast` (that one is easy to polyfill), in-class member initializer support for bitfields, designated initializers, defaulted comparison operator, concepts instead of SFINAE, and probably more. Our other infra is in the process of making this jump, or already has. This tests it out everywhere, across the various reference builds, to see if we have any issues. This is a bit more aggressive than I had previously communicated, but n - 1 is going to be a better long term place than n - 2. If we wanted to use `std::bit_cast` we would need one of: 1. GCC 11+ (~2.5 years old) 1. Clang 14 (~2.5 years old) 1. VS 16.11 (~2 years old) For mobile this means: 1. NDK 26 (still in Beta 😭) 1. XCode 14.3.0 (~6 months old) https://en.cppreference.com/w/cpp/compiler_support/20 That isn't quite doable yet, but we can start taking advantage of language features in the meantime. More of these will be supported in older toolchains. Anyone needing support for older C++ versions can lag behind on more recent changes. E.g. Yoga 2.0 supports C++ 14. bypass-github-export-checks Changelog: [Internal] Reviewed By: cortinico Differential Revision: D49261607 fbshipit-source-id: 38301204d56b7bc8410c2dda9c291da1b8d61ec1
128 lines
3.4 KiB
Plaintext
128 lines
3.4 KiB
Plaintext
/*
|
|
* Copyright (c) Meta Platforms, Inc. and affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
plugins {
|
|
id("com.android.library")
|
|
id("maven-publish")
|
|
id("signing")
|
|
}
|
|
|
|
group = "com.facebook.yoga"
|
|
|
|
val compileSdkVersionProperty: Int by rootProject.extra
|
|
val minSdkVersionProperty: Int by rootProject.extra
|
|
val targetSdkVersionProperty: Int by rootProject.extra
|
|
val buildToolsVersionProperty: String by rootProject.extra
|
|
val ndkVersionProperty: String by rootProject.extra
|
|
|
|
android {
|
|
namespace = "com.facebook.yoga"
|
|
compileSdk = 34
|
|
buildToolsVersion = "34.0.0"
|
|
ndkVersion = "25.1.8937393"
|
|
|
|
defaultConfig {
|
|
minSdk = 21
|
|
consumerProguardFiles("proguard-rules.pro")
|
|
|
|
ndk { abiFilters.addAll(setOf("x86", "x86_64", "armeabi-v7a", "arm64-v8a")) }
|
|
}
|
|
|
|
externalNativeBuild { cmake { path("CMakeLists.txt") } }
|
|
|
|
compileOptions {
|
|
targetCompatibility(JavaVersion.VERSION_1_8)
|
|
sourceCompatibility(JavaVersion.VERSION_1_8)
|
|
}
|
|
|
|
sourceSets {
|
|
named("main") {
|
|
java.srcDir("com")
|
|
manifest.srcFile("AndroidManifest.xml")
|
|
res.srcDir("res")
|
|
}
|
|
}
|
|
|
|
publishing {
|
|
multipleVariants {
|
|
withSourcesJar()
|
|
withJavadocJar()
|
|
includeBuildTypeValues("debug", "release")
|
|
}
|
|
}
|
|
}
|
|
|
|
dependencies {
|
|
implementation("com.google.code.findbugs:jsr305:3.0.2")
|
|
implementation("com.facebook.soloader:soloader:0.10.5")
|
|
testImplementation("junit:junit:4.12")
|
|
}
|
|
|
|
version =
|
|
if ("USE_SNAPSHOT".byProperty.toBoolean()) {
|
|
"${"VERSION_NAME".byProperty}-SNAPSHOT"
|
|
} else {
|
|
"VERSION_NAME".byProperty.toString()
|
|
}
|
|
|
|
publishing {
|
|
publications {
|
|
register<MavenPublication>("default") {
|
|
groupId = project.group.toString()
|
|
artifactId = project.name
|
|
version = project.version.toString()
|
|
afterEvaluate { from(components["default"]) }
|
|
pom {
|
|
description.set(
|
|
"An embeddable and performant flexbox layout engine with bindings for multiple languages")
|
|
name.set(project.name)
|
|
url.set("https://github.com/facebook/yoga.git")
|
|
licenses {
|
|
license {
|
|
name.set("MIT License")
|
|
url.set("https://github.com/facebook/yoga/blob/main/LICENSE")
|
|
distribution.set("repo")
|
|
}
|
|
}
|
|
developers {
|
|
developer {
|
|
id.set("Meta Open Source")
|
|
name.set("Meta Open Source")
|
|
email.set("opensource@meta.com")
|
|
}
|
|
}
|
|
scm { url.set("scm:git:git@github.com:facebook/yoga.git") }
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
val signingKey = "SIGNING_KEY".byProperty
|
|
val signingPwd = "SIGNING_PWD".byProperty
|
|
|
|
if (signingKey.isNullOrBlank() || signingPwd.isNullOrBlank()) {
|
|
logger.info("Signing disabled as the GPG key was not found")
|
|
} else {
|
|
logger.info("GPG Key found - Signing enabled")
|
|
}
|
|
|
|
signing {
|
|
useInMemoryPgpKeys(signingKey, signingPwd)
|
|
sign(publishing.publications)
|
|
isRequired = !(signingKey.isNullOrBlank() || signingPwd.isNullOrBlank())
|
|
}
|
|
|
|
// Fix for https://youtrack.jetbrains.com/issue/KT-46466/
|
|
// On Gradle 8+, the signing task is not correctly wired to the publishing tasks.
|
|
// This requires a fix on KGP that is currently pending.
|
|
val signingTasks = tasks.withType<Sign>()
|
|
|
|
tasks.withType<AbstractPublishToMaven>().configureEach { dependsOn(signingTasks) }
|
|
|
|
val String.byProperty: String?
|
|
get() = providers.gradleProperty(this).orNull
|