f2b4e42ca2
Summary: X-link: https://github.com/facebook/react-native/pull/37349 Pull Request resolved: https://github.com/facebook/yoga/pull/1288 Fixes https://github.com/facebook/yoga/issues/1283 New versions of CMake add "policies" which control how the build system acts wrt breaking changes. By default, CMake will emulate the behavior of the version specified in `cmake_minimum_required`. Setting a policy to true (to opt into new behavior where `cmake_minimum_required` is lower than the current version) seems actually just error out on the old versions. Googling around, apparently the way I should be doing this is to specify `<policy_max>` as part of `cmake_minimum_required `. https://gitlab.kitware.com/cmake/cmake/-/issues/20392 This should I think use new policies introduced up to 3.26 (what we test on right now), while letting 3.13 be the minimum. Reviewed By: cortinico Differential Revision: D45724864 fbshipit-source-id: 120cc2015a043605e7c07ef0459667643a4284b7
53 lines
1.3 KiB
CMake
53 lines
1.3 KiB
CMake
# Copyright (c) Meta Platforms, Inc. and affiliates.
|
|
#
|
|
# This source code is licensed under the MIT license found in the
|
|
# LICENSE file in the root directory of this source tree.
|
|
|
|
cmake_minimum_required(VERSION 3.13...3.26)
|
|
project(yoga-all)
|
|
set(CMAKE_VERBOSE_MAKEFILE on)
|
|
|
|
include(${CMAKE_CURRENT_SOURCE_DIR}/cmake/project-defaults.cmake)
|
|
|
|
add_subdirectory(yoga)
|
|
add_subdirectory(tests)
|
|
|
|
# cmake install config
|
|
include(GNUInstallDirs)
|
|
include(CMakePackageConfigHelpers)
|
|
|
|
# declare target to install
|
|
install(TARGETS yogacore EXPORT yoga-targets
|
|
LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
|
|
ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
|
|
INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
|
|
)
|
|
|
|
# install header files
|
|
install(DIRECTORY
|
|
"${CMAKE_CURRENT_LIST_DIR}/yoga"
|
|
DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
|
|
FILES_MATCHING PATTERN "*.h"
|
|
)
|
|
|
|
# install target config
|
|
install(EXPORT yoga-targets
|
|
FILE yogaTargets.cmake
|
|
NAMESPACE yoga::
|
|
DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/yoga
|
|
)
|
|
|
|
|
|
# generate config file
|
|
configure_package_config_file(
|
|
${CMAKE_CURRENT_SOURCE_DIR}/cmake/yoga-config.cmake.in
|
|
${CMAKE_CURRENT_BINARY_DIR}/yogaConfig.cmake
|
|
INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/yoga
|
|
)
|
|
|
|
# install config file
|
|
install(FILES
|
|
${CMAKE_CURRENT_BINARY_DIR}/yogaConfig.cmake
|
|
DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/yoga
|
|
)
|